Konversi masehi ke Pasaran Jawa dan Hijriah dengan metode Julian Date

Julian Date

Julian date adalah tetapan bilangan penanggalan matahari yang dihitung semenjak siang tanggal 1 Januari 4713 SM.

Penanggalan Hijriah

Tanggal 1 Muharram tahun pertama sama dengan bilangan Julian 1948439.5.

Penanggalan Jawa

Sistem Pasaran Jawa memadukan metode penanggalan Hindu, Hijriah dan Julian. Keistimewaan lainnya adalah memiliki siklus pekan, siklus pasaran, siklus wuku, siklus windu.

Sketch program konversi masehi ke pasaran jawa dan Hijriah:

#define epochHijriah          1948439.5f //math.harvard.edu
#define tambahKurangHijriah   0

struct TanggalDanWaktu
{
  uint8_t detik;
  uint8_t menit;
  uint8_t jam;
  uint8_t hari;
  uint8_t tanggal;
  uint8_t bulan;
  uint8_t tahun;
};
struct Tanggal
{
  uint8_t tanggal;
  uint8_t bulan;
  uint16_t tahun;
};
struct TanggalJawa
{
  uint8_t pasaran;
  uint8_t wuku;
  uint8_t tanggal;
  uint8_t bulan;
  uint16_t tahun;
};
struct JamDanMenit
{
  uint8_t jam;
  uint8_t menit;
};

uint8_t jumlahHariPerBulan[] = { 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31 };
char namaBulanMasehi[][10] = {"Januari", "Februari", "Maret", "April", "Mei", "Juni", "Juli", "Agustus", "September", "Oktober",
                            "November", "Desember"
                           };
char namaHariMasehi[][7] = {"Minggu", "Senin", "Selasa", "Rabu", "Kamis", "Jum'at", "Sabtu",};
char namaBulanHijriah[][14] = {"Muharram", "Safar", "Rabiul awal", "Rabiul akhir", "Jumadil awal", "Jumadil akhir", "Rajab",
                             "Sya'ban", "Ramadhan", "Syawal", "Dzulkaidah", "Dzulhijjah"
                            };
char namaBulanJawa[][12] = { "Sura", "Sapar", "Mulud", "Bakda Mulud", "Jumadilawal", "Jumadilakir", "Rejeb", "Ruwah", "Pasa",
                           "Sawal", "Sela", "Besar"
                         };
char namaWukuJawa[][13] = {"Shinta", "Landhep", "Wukit", "Kurantil", "Tala", "Gumbreg", "Warigalit", "Warigagung", "Julungwangi",
                         "Sungsang", "Galungan", "Kuningan", "Langkir", "Mandasia", "Julungpujut", "Pahang", "Kuruwelut", "Mrakeh", "Tambir",
                         "Madangkungan", "Maktal", "Wuye", "Manahil", "Prangbakat", "Bala", "Wungu", "Wayang", "Kulawu", "Dhukut", "Watugunung"
                        };
char namaHariPasaran[][7] = {"Legi", "Pahing", "Pon", "Wage", "Kliwon"};

TanggalDanWaktu tanggalMasehi;
Tanggal tanggalHijriah;
TanggalJawa tanggalJawa;
JamDanMenit waktuMagrib;

void setup() {
  Serial.begin(9600);
  Serial.println("Konversi Penanggalan Masehi ke Hijriah (metode Julian)");
  Serial.println("https://www.project.semesin.com/");
  Serial.println();
}

void loop() {
  waktuMagrib = {18, 12};

  uint32_t jumlahHari;
  double jumlahHariMatahari;

  tanggalMasehi.jam = 12;
  tanggalMasehi.menit = 0;
  tanggalMasehi.detik = 0;

  tanggalMasehi.tanggal = 8;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  tanggalMasehi.tanggal = 9;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  tanggalMasehi.tanggal = 10;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  tanggalMasehi.tanggal = 11;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  tanggalMasehi.tanggal = 12;
  tanggalMasehi.bulan = 9;
  tanggalMasehi.tahun = 18;

  tanggalMasehi.hari = hariDariTanggal(tanggalMasehi);
  masehiKeHijriah(tanggalMasehi, waktuMagrib, tambahKurangHijriah, tanggalHijriah, tanggalJawa);
  printKonversi(tanggalMasehi, tanggalHijriah, tanggalJawa);

  while (1);
}

double get_julian_date(Tanggal tanggal)
{
  if (tanggal.bulan <= 2)
  {
    tanggal.tahun -= 1;
    tanggal.bulan += 12;
  }

  double a = floor(tanggal.tahun / 100.0);
  double b = 2 - a + floor(a / 4.0);

  if (tanggal.tahun < 1583)
    b = 0;
  if (tanggal.tahun == 1582) {
    if (tanggal.bulan > 10)
      b = -10;
    if (tanggal.bulan == 10) {
      b = 0;
      if (tanggal.tanggal > 4)
        b = -10;
    }
  }

  return floor(365.25 * (tanggal.tahun + 4716)) + floor(30.6001 * (tanggal.bulan + 1)) + tanggal.tanggal + b - 1524.5;
}

double konversiTanggalHijriahKeJulianDate(uint16_t tahun, uint8_t bulan, uint8_t tanggal)
{
  return (epochHijriah + tanggal + ceil(29.5 * (bulan - 1)) + (354L * (tahun - 1)) + floor((3 + (11 * tahun)) / 30)) - 1;
}

void masehiKeHijriah(TanggalDanWaktu masehi, JamDanMenit waktuSholatMagrib, int8_t koreksiHijriah, Tanggal &hijriah, TanggalJawa &jawa)
{
  uint16_t sisaHari;
  double julianDate = get_julian_date({masehi.tanggal, masehi.bulan, masehi.tahun + 2000});

  uint16_t menitMagrib = waktuSholatMagrib.jam * 60  + waktuSholatMagrib.menit;
  uint16_t menitSekarang = masehi.jam * 60 + masehi.menit;

  if (menitSekarang >= menitMagrib)
  {
    julianDate++;//Pergantian hari hijrah pada magrib
  }

  julianDate = floor(julianDate) + 0.5;

  Tanggal tanggalHijriah;

  hijriah.tahun = floor(((30 * (julianDate - epochHijriah)) + 10646) / 10631);
  hijriah.bulan = min(12.0, ceil((julianDate - (29 + konversiTanggalHijriahKeJulianDate(hijriah.tahun, 1, 1))) / 29.5) + 1);
  hijriah.tanggal = (julianDate - konversiTanggalHijriahKeJulianDate(hijriah.tahun, hijriah.bulan, 1)) + 1;

  long julianLong = (long)julianDate;
  jawa.pasaran = ((julianLong + 1) % 5); //0 = legi
  jawa.wuku = (((julianLong + 65) % 210) / 7); //0 = Shinta
  jawa.tanggal = hijriah.tanggal;
  jawa.bulan = hijriah.bulan;
  jawa.tahun = hijriah.tahun + 512;

}
uint8_t hariDariTanggal(TanggalDanWaktu tanggalDanWaktu) {
  uint16_t jumlahHari = tanggalDanWaktu.tanggal;
  for (uint8_t i = 1; i < tanggalDanWaktu.bulan; ++i)
    jumlahHari += jumlahHariPerBulan[i-1];
  if (tanggalDanWaktu.bulan > 2 && tanggalDanWaktu.tahun % 4 == 0)
    ++jumlahHari;
  jumlahHari += (365 * tanggalDanWaktu.tahun) + ((tanggalDanWaktu.tahun + 3) / 4) - 1;

  return ((jumlahHari + 6) % 7) + 1; // 1 Januari 2000 hari sabtu = 7
}

void printKonversi(TanggalDanWaktu tanggalMasehi, Tanggal tanggalHijriah, TanggalJawa tanggalJawa)
{
  Serial.print("Masehi :\t");
  Serial.print(namaHariMasehi[tanggalMasehi.hari-1]);
  Serial.print(", ");
  Serial.print(tanggalMasehi.tanggal);
  Serial.print(" ");
  Serial.print(namaBulanMasehi[tanggalMasehi.bulan - 1]);
  Serial.print(" ");
  Serial.println(tanggalMasehi.tahun + 2000);

  Serial.print("Hijriah :\t");
  Serial.print(tanggalHijriah.tanggal);
  Serial.print(" ");
  Serial.print(namaBulanHijriah[tanggalHijriah.bulan - 1]);
  Serial.print(" ");
  Serial.println(tanggalHijriah.tahun);

  Serial.print("Pasaran Jawa :\t");
  Serial.print(tanggalJawa.tanggal);
  Serial.print(" ");
  Serial.print(namaHariPasaran[tanggalJawa.pasaran]);
  Serial.print(", ");
  Serial.print(namaWukuJawa[tanggalJawa.wuku]);
  Serial.print(", ");
  Serial.print(namaBulanJawa[tanggalJawa.bulan - 1]);
  Serial.print(" ");
  Serial.println(tanggalJawa.tahun);
  Serial.println();
}

 

4 thoughts on “Konversi masehi ke Pasaran Jawa dan Hijriah dengan metode Julian Date

  1. Mas, saya coba sket di atas kok pasaran jawanya gak muncul ya? Adakah sket yang lebih simple lagi, Masehi ke Pasaran Jawa saja. Trims…

    1. Terima kasih infonya,
      Saya mencobanya dengan arduino mega, tetapi di uno tidak berfungsi karena keterbatasan memory
      Tapi sketch di halaman ini ‘sudah di perbarui’ dan bisa digunakan untuk uno

      untuk metode lebih sederhana
      https://www.project.semesin.com/2018/03/16/konversi-penanggalan-masehi-ke-hijriah-menggunakan-arduino/
      Catatan : Tahun Pasaran Jawa = Tahun Hijriah + 512
      hanya saja terdapat beberapa kelemahan pada pergantian tahun

      Paling tidak metode Julian Date lebih mendekati nilainya karena menggunakan perhitungan matematis untuk memperkirakan posisi Bulan dan Matahari.

  2. Selamün Aleyküm

    Konversi Penanggalan Masehi ke Hijriah (metode Julian)
    https://www.project.semesin.com/

    Masehi :Senin, 14 Desember 2020
    Hijriah :28 Rabiul akhir 1442 = SALAH
    Pasaran Jawa :28 Wage, Prangbakat, Bakda Mulud 1954

    Masehi :Selasa, 15 Desember 2020
    Hijriah :29 Rabiul akhir 1442 = SALAH
    Pasaran Jawa :29 Kliwon, Prangbakat, Bakda Mulud 1954

    Masehi :Rabu, 16 Desember 2020
    Hijriah :1 Jumadil awal 1442
    Pasaran Jawa :1 Legi, Prangbakat, Jumadilawal 1954

    Masehi :Kamis, 17 Desember 2020
    Hijriah :2 Jumadil awal 1442
    Pasaran Jawa :2 Pahing, Prangbakat, Jumadilawal 1954

    Masehi :Jum’at, 18 Desember 2020
    Hijriah :3 Jumadil awal 1442
    Pasaran Jawa :3 Pon, Prangbakat, Jumadilawal 1954

    Kode yang dapat Anda lakukan untuk Turki.
    Kode salah ditampilkan. Terima kasih.
    Silahkan

    Hitung yang benar untuk Turki

    Masehi :Senin, 14 Desember 2020 = benar
    Hijriah :29 Rabiul akhir 1442

    Masehi :Selasa, 15 Desember 2020 = benar
    Hijriah :30 Rabiul akhir 1442

    Masehi :Rabu, 16 Desember 2020
    Hijriah :1 Jumadil awal 1442

Leave a Reply

Your email address will not be published. Required fields are marked *