Papan skor arduino 3 panel P10 dengan kontrol android

Papan skor (score board) adalah papan tempat informasi dan hasil pertandingan yang dapat dilihat oleh semua orang yang berada di arena pertandingan dan penonton.

Papan skor dengan dot matrix (dmd) dengan kontrol android melalui bluetooth ini memiliki fitur :

  1. Tambah-kurang point, skor, waktu, dan ronde pertandingan serta reset point.
  2. Informasi running text yang bisa tampil di tengah pertandingan.
  3. Master reset untuk menginisialisasi semua informasi pertandingan.

Skema papan skor arduino

lepas ‘pin 0’ arduino – bluetooth saat upload sketch:

komponen papan skor bluetooth

  1. Arduino Uno
  2. 3 buah DMD Panel P10
  3. Bluetooth HC-05
  4. Android

Sketch/koding scoring board arduino dengan android melalui bluetooth

#include <SoftwareSerial.h>
#include <DMD_Semesin.h>
#include <fonts/Arial16.h>
#include <fonts/Arial_Black_16.h>
#include <fonts/SystemFont5x7.h>
#include <fonts/SystemFont5x7Gemuk.h>
#include <Wire.h>

//defenisi pin
#define pinOE         9
#define pinSCK        8
#define pinA          6
#define pinB          7

#define DISPLAYS_WIDE 3
#define DISPLAYS_HIGH 1

#define fontPembuka     Arial16
#define fontSkor        Arial_Black_16
#define fontInformasi   SystemFont5x7
#define fontWaktu       SystemFont5x7
#define fontRonde       SystemFont5x7Gemuk

SPIDMD dmd(DISPLAYS_WIDE, DISPLAYS_HIGH);

//SoftwareSerial bluetooth(2, 3);
#define bluetooth     Serial

byte pointA, pointB, skorA, skorB, ronde = 0;
uint16_t waktu = 0;
byte Arial14TengahY;
char strInformasi[200] = "Selamat Datang";
char bufferBluetooth[200];
bool pertandinganBerjalan;
long millisDetik;
long millisEfek;
byte detikSebelumnya = 60;
bool modeInformasi;

EfekMarque efekMarque;

enum perintah {
  initPerangkat,
  pointAplus,
  pointAminus,
  pointBplus,
  pointBminus,
  skorAplus,
  skorAminus,
  skorBplus,
  skorBminus,
  rondePlus,
  rondeMinus,
  menitPlus,
  menitMinus,
  text,
  resetPoint,
  resetSemua,
  mulai,
};

DMD_TextBox boxSkorA(dmd, 0, 0, 28, 16);
DMD_TextBox boxSkorB(dmd, 68, 0, 28, 16);

void setup() {
  Serial.begin(9600);
  bluetooth.begin(9600);

  Serial.println(F("Papan skor arduino 3 panel P10 dengan kontrol android"));
  Serial.println(F("https://www.project.semesin.com"));


  dmd.setBrightness(128);
  dmd.selectFont(fontPembuka);
  dmd.clearScreen();
  dmd.begin();
  dmd.drawString(0, 0, F("Papan Skor bluetooth"));
  delay(1000);
  dmd.clearScreen();

  efekMarque.mode = nonAktif;
  efekMarque.sumber = sumberRAM;
  efekMarque.font = fontInformasi;
  efekMarque.kiri = 28;
  efekMarque.atas = 0;
  efekMarque.tinggi = 8;
  efekMarque.lebar = 40;
  efekMarque.step = 1;
  efekMarque.skip = 0;

  tampilanUtama();

  Serial.println("Sistem dimulai");

  millisDetik = millis();
}

void loop() {
  if (millisDetik != millis() / 1000L)
  {
    millisDetik = millis() / 1000L;
    if (pertandinganBerjalan)
    {
      waktu++;

      if (!modeInformasi)
      {
        tampilanUtama();
      }
    }
  }

  if (millisEfek < millis() - 100)
  {
    millisEfek = millis();
    if (efekMarque.mode == XMinus)
    {
      dmd.marqueeXMinus(&efekMarque);
    }
    else
    {
      modeInformasi = false;
      tampilanUtama();
    }
  }

  if (bluetooth.available())
  {
    byte tokenMulai = bluetooth.read();
    Serial.println(tokenMulai, HEX);
    if (tokenMulai == 0xFE)
    {
      delay(2);
      byte perintah = bluetooth.read();
      delay(2);
      byte panjang = bluetooth.read();

      for (uint16_t i = 0; i < panjang; i++)
      {
        delay(2);
        char c = bluetooth.read();
        bufferBluetooth[i] = c;
      }
      delay(2);
      byte tokenSelesai = bluetooth.read();
      if (tokenSelesai == 0xFF)
      {
        uint16_t i;
        switch (perintah)
        {
          case initPerangkat:
            bluetooth.write(237);
            break;
          case pointAplus:
            pointA++;
            break;
          case pointAminus:
            pointA--;
            break;
          case pointBplus:
            pointB++;
            break;
          case pointBminus:
            pointB--;
            break;
          case skorAplus:
            skorA++;
            break;
          case skorAminus:
            skorA--;
            break;
          case skorBplus:
            skorB++;
            break;
          case skorBminus:
            skorB--;
            break;
          case rondePlus:
            ronde++;
            break;
          case rondeMinus:
            ronde--;
            break;
          case menitPlus:
            waktu += 60 ;
            break;
          case menitMinus:
            if (waktu > 60)
              waktu -= 60;
            else
              waktu = 0;
            break;
          case resetPoint:
            pointA = 0;
            pointB = 0;
            break;
          case resetSemua:
            pointA = 0;
            pointB = 0;
            skorA = 0;
            skorB = 0;
            ronde = 0;
            waktu = 0;
            break;
          case mulai:
            pertandinganBerjalan = !pertandinganBerjalan;
            break;
          case text:
            for (i = 0; i < panjang; i++)
            {
              strInformasi[i] = bufferBluetooth[i];
            }
            strInformasi[i] = 0;
            dmd.drawFilledBox(28, 0, 67, 7, GRAPHICS_OFF);
            efekMarque.init = true;
            efekMarque.alamat = strInformasi;
            efekMarque.mode = XMinus;
            efekMarque.clear = 40;
            modeInformasi = true;

            millisEfek = millis();
            break;
        }
        if (pointA == 255)
          pointA = 0;
        if (pointB == 255)
          pointB = 0;
        if (skorA == 255)
          skorA = 0;
        if (skorB == 255)
          skorB = 0;
        if (ronde == 255)
          ronde = 0;
        if (waktu == 3600)
          waktu = 0;

        if (!modeInformasi)
        {
          tampilanUtama();
        }
      }
    }
  }
}
byte bin2bcd(byte val)
{
  return val + 6 * (val / 10);
}

void tampilanUtama()
{
  byte lebarText;
  dmd.selectFont(fontSkor);
  Arial14TengahY = (dmd.height - dmd.fontHeader.height) / 2;

  boxSkorA.clear();
  boxSkorB.clear();
  lebarText = dmd.stringWidth(String(pointA));
  dmd.drawString((28 - lebarText) / 2 + 0, Arial14TengahY, String(pointA));
  lebarText = dmd.stringWidth(String(pointB));
  dmd.drawString((28 - lebarText) / 2 + 68, Arial14TengahY, String(pointB));


  dmd.selectFont(fontWaktu);
  char waktuStr[] = "00:00";
  byte menitBCD = bin2bcd(waktu / 60);
  byte detikBCD = bin2bcd(waktu % 60);
  waktuStr[0] = (menitBCD >> 4) + 0x30;
  waktuStr[1] = (menitBCD & 0x0F) + 0x30;
  waktuStr[3] = (detikBCD >> 4) + 0x30;
  waktuStr[4] = (detikBCD & 0x0F) + 0x30;
  lebarText = dmd.stringWidth(waktuStr);
  dmd.drawString((dmd.width - lebarText) / 2, 0, waktuStr);

  dmd.selectFont(fontRonde);

  dmd.drawString(28, 8, String(skorA));
  lebarText = dmd.stringWidth(String(skorB));
  dmd.drawString((68 - lebarText), 8, String(skorB));

  lebarText = dmd.stringWidth(String(ronde));
  dmd.drawString((dmd.width - lebarText) / 2, 8, String(ronde));
}

screenshot apk papan skor

File papan skor android

 

55 thoughts on “Papan skor arduino 3 panel P10 dengan kontrol android

    1. mekanisme komunikasi bluetoothnya hanya mengirimkan 1 byte sesuai perintah tanpa ada pengecekan (dibuat sederhana saja).
      kemungkinan permasalahannya pada komunikasi bluetooth yang tidak tepat,
      cek baudrate, cek rangkaian.

  1. gan saya rencana bikin counter barang menggunakan 2 arduino, yg satu menggunakan modul proximity sensor e18-d80nk kemudian mengirimkan hasil counter ke matrix led display 16 x 32 p10 menggunakan modul NRF24L01…masih bingung nih gan. soalnya matix display pake pin yg sama dgn nrf24…mungkin kah dibuat? soalnya saya sempat lihat ada yg membuat papan skor dgn modul yg serupa…bedanya saya pake modul proximity sensor sementara saya lihat dia cuma pake push button biasa…ada ide utk codingnya? simpel sebenernya tp bagian ngirim datanya ribet…

    1. bisa di buat, karena sama-sama menggunakan spi,
      tapi nrf24 hanya aktif ketika pin cs-nya aktif dengan catatan interupsi untuk matrix display-nya di off kan (tanpa mengganggu kualitas tampilan)

  2. Mohon pencerahan utk codingnya gan…ada email? saya kirim yg sudah saya buat…
    sejauh ini disisi counter sudah berfungsi dengan baik..tinggal menambah fungsi alarm dan reset back to zero
    sementara disisi display..selain gambarnya jd flicker, komunikasi pun tidak terjadi..
    apa krn saya pake arduino Nano ya gan? setelah googling..katanya harus pake kapasitor 10uF…
    oh satu lagi…library yg work buat modul ini pake library RF24 Network…pake lib nya RF24 dan Radiohead sama sekali gak fungsi…saya test pake example standar…ga ada komunikasi sama sekali…
    boleh konsultasi ya gan?

  3. terus mas, kalau buat countdown timer ke P10 , bisa ngak tanpa RTC ?? ada source code ngak mas , yg bisa di ikutin, untuk dmd2 library tentunya , terimakasih sebelumnya

  4. saya menemukan kesalahan disini.. ‘struct EfekMarqueClear’ has no member named ‘mulai’ kalau dihilangkan baru bener.. pake arduino 1.8.11 ..mohon pencerahannya gan ,terima kasih

  5. sama saja gan… masih eror ………..
    C:\Users\UDA\Documents\Arduino\libraries\DMD-semesin\DMD_Frame.cpp:3:10: fatal error: twi_Semesin_Bufferless.h: No such file or directory

    ResolveLibrary(twi_Semesin_Bufferless.h)
    -> candidates: []
    #include “twi_Semesin_Bufferless.h”

    ^~~~~~~~~~~~~~~~~~~~~~~~~~

    compilation terminated.

  6. Sudah saya coba pak, kedip hilang, tapi tulisan di poin A dan poin B ada masalah baru, kalau sudah 2 angka pada poinA apabila di reset hanya angka depan aja yg berubah jadi Nol. Digit kedua nya tidak mereset. Dan pada point B apabila di reset nilai poinnya ketimpa Angka Nol. Jadi terlihat seperti double. Adakah saran yang lain pak… Terimakasih

    1. baris 258,
      lebarText = dmd.stringWidth(String(pointA));
      dmd.drawString((28 – lebarText) / 2 + 0, Arial14TengahY, String(pointA));
      lebarText = dmd.stringWidth(String(pointB));
      dmd.drawString((28 – lebarText) / 2 + 68, Arial14TengahY, String(pointB));
      coba aja yang sesuai

    1. kemungkinan akan merusak hc-05
      belum pernah uji sampai dimana ketahanan hc-05
      setidaknya berdasarkan datasheet, tegangan operasi hc-05 maksimal 4.2v, jadi perlu resistor sebagai level converter agar hc-05 berjalan normal

Leave a Reply to yussep Cancel reply

Your email address will not be published. Required fields are marked *