Pengisi galon otomatis menggunakan arduino

Asep Kurniawan

Depot pengisian air minum menggunakan galon sebagai tempat air. Tahap-tahap pengisian yang lazim di lakukan adalah: pembersihan, pengisian, pemasangan tutup dan perbersihan.

Dalam artikel ini hanya melakukan otomatisasi pada tahap pengisian, cara kerjanya sebagai berikut :

  1. Saat mulai, sensor ir/obstacle mendeteksi keberadaan galon diatas tempat pengisian galon. Jika ada galon maka sistem menginformasikan agar galon diambil terlebih dahulu.
  2. Sistem menunggu hingga galon kosong ditempatkan pada posisi pengisian galon.
  3. Sistem akan menghidupkan pompa air, kemudian menghidupkan solenoid.
  4. Sensor flow meter akan menghitung volume ait yang dialirkan kedalam galon.
  5. Jika volume telah mencukupi maka solenoid dan pompa dimatikan.
  6. Jika selama pengisian galon, posisi galon bergeser atau diambil, maka solenoid dan pompa akan dimatikan.
  7. Sistem akan menunggu galon diambil.
  8. Selesai.

Skema pengisian galon otomatis berbasis arduino:

Komponen yang digunakan dalam perancangan sistem pengisian galon arduino:

  1. Arduino uno
  2. LCD 16×2 lcd backpack
  3. sensor obstacle
  4. flow sensor
  5. solenoid
  6. pompa air
  7. relay 2 channel

Program pengisi galon menggunakan arduino:

#define kapasitasGalon      19//liter
#define pulsaPerLiter       450//sesuai spesifikasi sensor water flow

#define pinWaterFlow        2
#define pinSensorIR         A0
#define pinPompa            7
#define pinSelenoid         6

#define IRAktif             LOW
#define relayAktif          LOW

#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <util/atomic.h>

LiquidCrystal_I2C lcd(0x3F, 16, 2);
volatile uint16_t pulseCount;

void setup() {
  digitalWrite(pinPompa, !relayAktif);
  digitalWrite(pinSelenoid, !relayAktif);
  pinMode(pinWaterFlow, INPUT);
  pinMode(pinSensorIR, INPUT);
  pinMode(pinPompa, OUTPUT);
  pinMode(pinSelenoid, OUTPUT);

  Serial.begin(9600);
  Serial.println(F("Pengisi galon otomatis"));
  Serial.println(F("https://www.semesin.com/project"));


  Wire.begin();
  Wire.beginTransmission(0x3F);
  if (Wire.endTransmission())
  {
    lcd = LiquidCrystal_I2C(0x27, 16, 2);
  }
  lcd.begin();

  lcd.backlight();
  lcd.print("Pengisi galon");
  lcd.setCursor(0, 1);
  lcd.print("Semesin.com");
  delay(3000);


  lcd.setCursor(0, 0);
  lcd.print("ambil Galon     ");
  while (digitalRead(pinSensorIR) == IRAktif); //deteksi awal : jika ada galon kosongkan dahulu

  attachInterrupt(digitalPinToInterrupt(pinWaterFlow), pulseCounter, FALLING);
}

void loop() {
  lcd.setCursor(0, 0);
  lcd.print("Letakkan Galon  ");
  while (digitalRead(pinSensorIR) == !IRAktif);

  delay(1000);//memastikan galon diletakkan

  if (digitalRead(pinSensorIR) == IRAktif)
  {
    lcd.setCursor(0, 0);
    lcd.print("Mengisi Galon...");

    pulseCount = 0;
    digitalWrite(pinPompa, relayAktif);
    delay(1000);
    digitalWrite(pinSelenoid, relayAktif);

    lcd.setCursor(0, 1);
    lcd.print("                ");
    uint16_t jumlahPulsa;

    while ((jumlahPulsa < kapasitasGalon * pulsaPerLiter) && (digitalRead(pinSensorIR) == IRAktif))
    {
      ATOMIC_BLOCK(ATOMIC_FORCEON)
      {
        jumlahPulsa = pulseCount;
      }

      lcd.setCursor(0, 1);
      lcd.print((1.0 * jumlahPulsa / pulsaPerLiter));
      lcd.print(" liter");
    }

    digitalWrite(pinSelenoid, !relayAktif);
    delay(100);
    digitalWrite(pinPompa, !relayAktif);

    lcd.setCursor(0, 0);
    if (jumlahPulsa >= kapasitasGalon * pulsaPerLiter)
    {
      lcd.print("Galon penuh     ");
    }
    else if (digitalRead(pinSensorIR) != IRAktif)
    {
      lcd.print("Galon tidak ada ");
    }

    delay(1000);
    lcd.setCursor(0, 0);
    lcd.print("silahkan ambil  ");

    while (digitalRead(pinSensorIR) == IRAktif);
    delay(1000);//memastikan galon sudah diambil
    while (digitalRead(pinSensorIR) == IRAktif);
  }
}

void pulseCounter()
{
  pulseCount++;
}

Library:

Bagikan Link halaman ini :

24 thoughts on “Pengisi galon otomatis menggunakan arduino”

  1. Saya mau membuat pengisian dengan variasi dari ml-liter dengan masukan dari keypad dan dapat disimpan ke memori sebagai menu favorit yg akan dibaca oleh tombol khusus. Kebutuhan saya untuk produksi saya dalam bentuk cairan dan pengisian ke botol2 yang bervariasi dari 10ml – 1000ml. Sy punya dasar untuk pemrograman dan hardware arduino.
    Mohon arahannya agar keinginan saya untuk alat tersebut bisa diwujudkan.
    Terima kasih

    Balas

    1. banyak cara untuk interface keypad dengan arduino, salah satunya dengan metode ‘menu’
      misalnya set key ‘A’ untuk 10ml, ‘B’ untuk 200ml serta setting lainnya (kalibrasi, stop time dll) bisa di set melalui keypad dengan menu-submenu

  2. maaf master saya mau tanya nih …proyek ini saya copas dan bekerja sempurna sewaktu di upluod
    dan sewaktu di gunakan juga baik,yang saya heran sewaktu pengisian botol ke 2 dan selanjut nya alat tidak berfungsi seperti pengisian botol yg pertama….
    sebelom air berjalan relay hidup 1 detik..

    Balas

    1. “sebelom air berjalan relay hidup 1 detik..” memang seperti itu di programkan

          digitalWrite(pinPompa, relayAktif);
    delay(1000);
    digitalWrite(pinSelenoid, relayAktif);

    1. masing-masing komponen punya fungsi sendiri2,
      selenoid berfungsi menjaga air tetap di pipa (tidak surut) dan juga sebagai pen-stop (seketika) jika galon telah penuh
      sensor obstacle berfungssi untuk memastikan galon berada di posisinya sehingga jika galon tidak di posisi maka pengisian akan di batalkan
      tanpa obstacle dan selenoid alat masih bisa berjalan, dengan catatan:
      1. jumper pin obstacle ke ground (LOW)
      2. hapus baris 105-107

  5. Kalau mau di bikin 2 pengisiian, apakah pin 3 bisa di jadikan input pin flowmeter nya mas atau mesti pake arduino Mega..

    Balas

  6. saya menyelipkan/menggabung coding untuk mengubah variable #pulsaPerLiter degan menu level menggunakan 4 push button. dengan code if (!digitalRead(pinMenu)) { dst.
    saya pake pin A2dst. tetapi tidak tampil / jalan di loop. fungsi itu cuma berjalan ketika ketika lcd menampilkan “letakan galon” trus sensor IR LOW. jadi tidak serta merta ketika saya push menu button muncul fungsi menu. mohon bantuan coding bagaimana solusi agar tiap push menu. tampil void tampilan menu.

    Balas

  7. Saya mau tanya
    Apakah bisa menggunakan termostat suhu(ada indikator setelah suhu yang biasa terdapat pada termostat tetas ayam) kemudian pada sesor suhu di rubah menjadi load cell(sensor berat) ??

    Apakah bisa berkerja/konek ?

    Saya melihat harga filler diatas 3 jutaan semua apabila menggunakan metode diatas makan akan sangat jauh biaya harga filler tsb.
    Note: saya hanya ingin membuat filler murah meriah.

    Balas

    1. konsepnya memungkinkan, kira2 seperti timbangan mekanis, ketika plat logammnya di beri beban akan melengkung dan menyentuh ‘saklar’
      tentu perlu penyesuaian kekuatan mekanis juga, misal thermostat kekuatan plat logammnya mesti di uji langsung dengan berat tertentu.

    1. memungkinkan untuk dibuat, dengan cara menambahkan mekanis dan kode2 pengecekan (misal cek jumlah koin2) dan melakukan aktifasi pengisian jika kondisinya sesuai

    1. util/atomic.h adalah library bawaan arduino yang khusus hanya untuk arduino/microcontroler 8 bit, jika menggunakan esp/stm32 library itu tidak di perlukan (bisa di tiadakan beserta kode bawaannya)

    1. Counter-nya mengulang jika mati lampu,
      supaya tidak mengulang bisa di tambahkan mekanisme penyimpanan di EEPROM, hanya saja terbatas lifetime EEPROM-nya karena hanya mampu tulis baca 100rb kali.

  12. master saya mau nanya, untuk kapasitas galon 19 liter itu udah sesuai dari define ya? Jadi gausah di buat hitung hitungannya?

    Makaasih

    Balas

    1. ada bermacam kapasitas galon air diantaranya 10, 12, 18, 19 liter, baris 

      #define kapasitasGalon      19//liter

      bisa disesuaikan untuk ukuran galon yang akan di isi

      sedangkan baris 

      #define pulsaPerLiter       450//sesuai spesifikasi sensor water flow

      disesuaikan dengan jenis sensor flow yang digunakan

Tinggalkan Balasan

Alamat email Anda tidak akan dipublikasikan.